Récuperer Ca Clés De Son Windows Simplement Avec Un Script .Vbs

Forums Entraide & Partage Système d’exploitation Récuperer Ca Clés De Son Windows Simplement Avec Un Script .Vbs

Affichage de 1 message (sur 1 au total)
  • Auteur
    Messages
  • #11205 Répondre
    RaZor_Monst3r
    Participant

    AstuceRécuperer Ca Clés De Son Windows Simplement Avec Un Script .Vbs

    Bonsoir à tous ,

    J’étais gentillement en train ranger un peu mon foutoire de gigatribe et du reste ,
    quand je me suis décider a reverifier certains script que j avais mis de cotè .

    D’ou la sortie de cette astuce du fond de mes partages !

    Pour vous dire la source là 😮 j ai un beug ,mais je la remercis !

    Donc voilà nous sommes tous un jour ou l autres a devoir « trouver ou connaitre » ça clés de son windows !
    Que ce soit pour une réinstallation après des test ou après avoir installer un autre système …

    Ou Simplement pour reinstaller sont windows sur une autre machine avec ca propre clés de sont anciens pc !

    vous direz il existe des logiciels qui le font très bien !Oui je sait .

    Mais la mon astuce ce fait simplement depuis un script (.vbs)
    Ce script fonctionne sur Windows 7, 8, 8.1 et Windows 10.

    Copiez le code ci-dessous dans un document texte (sur votre bureaux) et enregistrez le fichier en tant que :

    GetProductKey.vbs

    donc nouveau document texte.txt deviendras GetProductKey.vbs

    voici le script a copier coller :

    Option Explicit 
     
    Dim objshell,path,DigitalID, Result 
    Set objshell = CreateObject("WScript.Shell")
    'Set registry key path
    Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
    'Registry key value
    DigitalID = objshell.RegRead(Path & "DigitalProductId")
    Dim ProductName,ProductID,ProductKey,ProductData
    'Get ProductName, ProductID, ProductKey
    ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
    ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
    ProductKey = "Installed Key: " & ConvertToKey(DigitalID) 
    ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
    'Show messbox if save to a file 
    If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
       Save ProductData 
    End If
     
    'Convert binary to chars
    Function ConvertToKey(Key)
        Const KeyOffset = 52
        Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
        'Check if OS is Windows 8
        isWin8 = (Key(66) \ 6) And 1
        Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
        i = 24
        Maps = "BCDFGHJKMPQRTVWXY2346789"
        Do
               Current= 0
            j = 14
            Do
               Current = Current* 256
               Current = Key(j + KeyOffset) + Current
               Key(j + KeyOffset) = (Current \ 24)
               Current=Current Mod 24
                j = j -1
            Loop While j >= 0
            i = i -1
            KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
            Last = Current
        Loop While i >= 0 
         
        If (isWin8 = 1) Then
            keypart1 = Mid(KeyOutput, 2, Last)
            insert = "N"
            KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
            If Last = 0 Then KeyOutput = insert & KeyOutput
        End If     
       
        ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
        
    End Function
    'Save data to a file
    Function Save(Data)
        Dim fso, fName, txt,objshell,UserName
        Set objshell = CreateObject("wscript.shell")
        'Get current user name 
        UserName = objshell.ExpandEnvironmentStrings("%UserName%") 
        'Create a text file on desktop 
        fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
        Set fso = CreateObject("Scripting.FileSystemObject")
        Set txt = fso.CreateTextFile(fName)
        txt.Writeline Data
        txt.Close
    End Function

    Double-cliquez pour exécuter le script afin de trouver la clé de produit de votre système Windows.

    Vous pouvez si vous le désirer la sauvegarder (.txt),vous aurez ex: Windows10 Home ,Product id,et La Clés ..

    j’espère que cette astuce vous sera autant utile qu’a moi mème 😉

Affichage de 1 message (sur 1 au total)
Répondre à : Récuperer Ca Clés De Son Windows Simplement Avec Un Script .Vbs

Vous pouvez utiliser les BBCodes pour formater votre contenu.
Your account can't use Advanced BBCodes, they will be stripped before saving.

Vos informations: